pro geocorrect_glt,imgfname, ns, nl, nb, nloffset, gltfname, gltns, gltnl,ofname

; purpose: using an input .glt file, geocorrect an input image
;
; parameters:
;          imgfname - input image file name - must be BIP, integer values
;          ns, nl, nb - number of samples, lines, and bands for avfname
;          nloffset - the starting line of this image if it were to be part
;                     of the complete mosaic.  This is a 1-based value (i.e.
;                     the starting line of the second aviris cube in a mosaic
;                     would be 513).
;          gltfname - the .glt file 
;          gltns, gltnl - number of samples and lines for gltfname
;          ofname - output file name
;

nullspec = intarr(nb)
nullspec(*) = 0
spectrum = intarr(nb)
gltline = intarr(gltns,2)

openr,img_lun,/get, imgfname
openr,glt_lun,/get, gltfname
openw,outf_lun,/get, ofname

for i = 0,gltnl-1 do begin
  readu, glt_lun, gltline
;  byteorder, gltline
   for j = 0,gltns-1 do begin
    if (gltline(j,0) eq 0 or gltline(j,1) eq 0) then begin
      writeu, outf_lun, nullspec
    endif else begin
;      print,'gltline=', gltline
      file_pointer = (((long(abs(gltline(j,1)))-(nloffset-1))-1)*(ns*(nb*2)))+ $
                     ((abs(gltline(j,0))-1) * (nb*2))
;      print,'j,filepointer, ns, nl, nb, nloffset',j,file_pointer, ns, nl, nb, nloffset
      point_lun, img_lun, file_pointer
      readu, img_lun, spectrum
      writeu, outf_lun, spectrum
    endelse
  endfor
endfor

free_lun, img_lun, glt_lun, outf_lun

end